1/* Compute minimum of two numbers, regarding NaN as missing argument.
2 Copyright (C) 1997-2023 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <sysdep.h>
20#include <libm-alias-ldouble.h>
21
22 .text
23ENTRY(__fminl)
24 fldt 8(%rsp) // x
25 fldt 24(%rsp) // x : y
26
27 fucomi %st(1), %st
28 jp 2f
29 fcmovnb %st(1), %st
30
31 fstp %st(1)
32
33 ret
34
352: // Unordered.
36 fucomi %st(0), %st
37 jp 3f
38 // st(1) is a NaN; st(0) is not. Test if st(1) is signaling.
39 testb $0x40, 15(%rsp)
40 jz 4f
41 fstp %st(1)
42 ret
43
443: // st(0) is a NaN; st(1) may or may not be.
45 fxch
46 fucomi %st(0), %st
47 jp 4f
48 // st(1) is a NaN; st(0) is not. Test if st(1) is signaling.
49 testb $0x40, 31(%rsp)
50 jz 4f
51 fstp %st(1)
52 ret
53
544: // Both arguments are NaNs, or one is a signaling NaN.
55 faddp
56 ret
57END(__fminl)
58libm_alias_ldouble (__fmin, fmin)
59