1/* Save current context.
2 Copyright (C) 2002-2022 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <sysdep.h>
20#include <asm/prctl.h>
21
22#include "ucontext_i.h"
23
24/* int __getcontext (ucontext_t *ucp)
25
26 Saves the machine context in UCP such that when it is activated,
27 it appears as if __getcontext() returned again.
28
29 This implementation is intended to be used for *synchronous* context
30 switches only. Therefore, it does not have to save anything
31 other than the PRESERVED state. */
32
33
34ENTRY(__getcontext)
35 /* Save the preserved registers, the registers used for passing
36 args, and the return address. */
37 movq %rbx, oRBX(%rdi)
38 movq %rbp, oRBP(%rdi)
39 movq %r12, oR12(%rdi)
40 movq %r13, oR13(%rdi)
41 movq %r14, oR14(%rdi)
42 movq %r15, oR15(%rdi)
43
44 movq %rdi, oRDI(%rdi)
45 movq %rsi, oRSI(%rdi)
46 movq %rdx, oRDX(%rdi)
47 movq %rcx, oRCX(%rdi)
48 movq %r8, oR8(%rdi)
49 movq %r9, oR9(%rdi)
50
51 movq (%rsp), %rcx
52 movq %rcx, oRIP(%rdi)
53 leaq 8(%rsp), %rcx /* Exclude the return address. */
54 movq %rcx, oRSP(%rdi)
55
56#if SHSTK_ENABLED
57 /* Check if shadow stack is enabled. */
58 testl $X86_FEATURE_1_SHSTK, %fs:FEATURE_1_OFFSET
59 jz L(no_shstk)
60
61 /* Save RDI in RDX which won't be clobbered by syscall. */
62 movq %rdi, %rdx
63
64 xorl %eax, %eax
65 cmpq %fs:SSP_BASE_OFFSET, %rax
66 jnz L(shadow_stack_bound_recorded)
67
68 /* Get the base address and size of the default shadow stack
69 which must be the current shadow stack since nothing has
70 been recorded yet. */
71 sub $24, %RSP_LP
72 mov %RSP_LP, %RSI_LP
73 movl $ARCH_CET_STATUS, %edi
74 movl $__NR_arch_prctl, %eax
75 syscall
76 testq %rax, %rax
77 jz L(continue_no_err)
78
79 /* This should never happen. */
80 hlt
81
82L(continue_no_err):
83 /* Record the base of the current shadow stack. */
84 movq 8(%rsp), %rax
85 movq %rax, %fs:SSP_BASE_OFFSET
86 add $24, %RSP_LP
87
88 /* Restore RDI. */
89 movq %rdx, %rdi
90
91L(shadow_stack_bound_recorded):
92 /* Get the current shadow stack pointer. */
93 rdsspq %rax
94 /* NB: Save the caller's shadow stack so that we can jump back
95 to the caller directly. */
96 addq $8, %rax
97 movq %rax, oSSP(%rdx)
98
99 /* Save the current shadow stack base in ucontext. */
100 movq %fs:SSP_BASE_OFFSET, %rax
101 movq %rax, (oSSP + 8)(%rdi)
102
103L(no_shstk):
104#endif
105 /* We have separate floating-point register content memory on the
106 stack. We use the __fpregs_mem block in the context. Set the
107 links up correctly. */
108
109 leaq oFPREGSMEM(%rdi), %rcx
110 movq %rcx, oFPREGS(%rdi)
111 /* Save the floating-point environment. */
112 fnstenv (%rcx)
113 fldenv (%rcx)
114 stmxcsr oMXCSR(%rdi)
115
116 /* Save the current signal mask with
117 rt_sigprocmask (SIG_BLOCK, NULL, set,_NSIG/8). */
118 leaq oSIGMASK(%rdi), %rdx
119 xorl %esi,%esi
120#if SIG_BLOCK == 0
121 xorl %edi, %edi
122#else
123 movl $SIG_BLOCK, %edi
124#endif
125 movl $_NSIG8,%r10d
126 movl $__NR_rt_sigprocmask, %eax
127 syscall
128 cmpq $-4095, %rax /* Check %rax for error. */
129 jae SYSCALL_ERROR_LABEL /* Jump to error handler if error. */
130
131 /* All done, return 0 for success. */
132 xorl %eax, %eax
133 ret
134PSEUDO_END(__getcontext)
135
136weak_alias (__getcontext, getcontext)
137